Porte automatique autonome de mon poulailler (sur panneau solaire)

#include <avr/power.h>  //Gestion de la consommation
#include <avr/sleep.h>  //Gestion de la consommation
#include <avr/wdt.h>    //Gestion de la consommation
#include <Stepper.h>    //Moteur pas à pas

//DEBUG
//#define DEBUG_WITH_SERIAL

///////////
// TYPES //
///////////

enum LIGHTLEVEL
{
  LIGHTLEVEL_DAY = 0,
  LIGHTLEVEL_NIGHT,
  LIGHTLEVEL_NS
};


////////////////
// CONSTANTES //
////////////////

// -- GENERAL --
#define NIGHT_THRESHOLD_VALUE  85    //Valeur de la photoresistance pour passer en mode nuit
#define DAY_THRESHOLD_VALUE    300    //Valeur de de la photoresistance pour passer en mode jour
#define NB_LIGHT_LEVEL_NEEDS    2      //Nombre de détection successive avant de considérer l'état (jour ou nuit).

#define MOTOR_STEPS_COUNT      48*42.5 //48 pas avec un reducteur de 1/42.5
#define MOTOR_SPEED            8      //Vitesse de 1 à 10

// -- ANALOG INPUT --
#define AIN_PHOTORESISTANCE  A0

// -- DIGITAL INPUT --
#define DIN_DOOROPENED      2
#define DIN_DOORCLOSED      3

// -- DIGITAL OUT --
#define DOUT_PWM6        6
#define DOUT_PWM9        9
#define DOUT_PWM11        11
#define DOUT_PWM10        10

// -- WATCHDOG TIMEOUT --
#define WDT_EVT_PERIOD  WDT_8S

#define WDT_16MS  0
#define WDT_32MS  1
#define WDT_64MS  2
#define WDT_125MS  3
#define WDT_250MS  4
#define WDT_500MS  5
#define WDT_1S    6
#define WDT_2S    7
#define WDT_4S    8
#define WDT_8S    9

                    //  WDP3 | WDP2 | WDP1 | WDP0
const byte WDT[][4]{{    0  ,  0  ,  0  ,  0  },    //WDT_16MS
                    {    0  ,  0  ,  0  ,  1  },    //WDT_32MS
                    {    0  ,  0  ,  1  ,  0  },    //WDT_64MS
                    {    0  ,  0  ,  1  ,  1  },    //WDT_125MS
                    {    0  ,  1  ,  0  ,  0  },    //WDT_250MS
                    {    0  ,  1  ,  0  ,  1  },    //WDT_500MS
                    {    0  ,  1  ,  1  ,  0  },    //WDT_1S
                    {    0  ,  1  ,  1  ,  1  },    //WDT_2S
                    {    1  ,  0  ,  0  ,  0  },    //WDT_4S
                    {    1  ,  0  ,  0  ,  1  },    //WDT_8S
                  };


///////////////
// VARIABLES //
///////////////

// -- GENERAL --
Stepper g_stepperMotor(MOTOR_STEPS_COUNT, DOUT_PWM9, DOUT_PWM11, DOUT_PWM10, DOUT_PWM6);

LIGHTLEVEL g_ePreviousLightLevelState = LIGHTLEVEL_NS;
unsigned int g_uiSameLightLevelOccurence = 0;

// -- WATCHDOG TIMEOUT --
volatile bool gv_bWdtEvt = true; //Flag signalant l'evenement du watchdog timer


///////////////
// FONCTIONS //
///////////////

// -- WATCHDOG TIMEOUT --

//Configuration du watchdog
void SetupWatchdog()
{
  MCUSR &= ~(1 << WDRF);  //Reset du flag de status 
  WDTCSR |= (1 << WDCE) | (1 << WDE);  //Autoriser le changement de configuration
 
  //Configuration du prescaler pour divisier la frequence de l'horloge => (2048<<i)/128000 avec i = WDT_16MS à WDT_8S
  WDTCSR = (WDT[WDT_EVT_PERIOD][3] << WDP0) | (WDT[WDT_EVT_PERIOD][2] << WDP1) | (WDT[WDT_EVT_PERIOD][1] << WDP2)| (WDT[WDT_EVT_PERIOD][0] << WDP3);
 
  WDTCSR |= (1 << WDIE); //Activer le mode interrupt
}

// --INTERRUPTIONS --

//Interrupt Service Routine du WDT
ISR(WDT_vect)
{
  if(gv_bWdtEvt == false)
  {
    gv_bWdtEvt = true; //Signaler l'interruption (si nous ne sommes pas déjà en train de traiter la précédente)
  }
}

// -- GESTION DE LA MISE EN VEILLE --

//Extinction du micro controleur
void EnterPowerDown()
{
  gv_bWdtEvt = false; //Reset du flag
 
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);  //IDLE, ADC, PWR_SAVE, STANDBY, PWR_DOWN
  sleep_enable();
  sleep_mode();

  //Le programme reprend ici lors d'une interruption

  sleep_disable(); // La 1ère chose à faire est de désactiver le mode veille
}


// -- INPUT/OUTPUT --
void SetupInputOutputPin()
{
  pinMode(DIN_DOOROPENED, INPUT);
  pinMode(DIN_DOORCLOSED, INPUT);
}
void SetupSerial()
{
  Serial.begin(9600);
}

// -- GENERAL --
void SetupMotorSpeed(int iSpeed)
{
  if(iSpeed > 10)
    iSpeed = 10;   
  else if(iSpeed < 1)
    iSpeed = 1;
   
  g_stepperMotor.setSpeed(iSpeed);
}

void OpenTheDoor()
{
  int iStateDoorOpenedSensor;
  iStateDoorOpenedSensor = digitalRead(DIN_DOOROPENED); 
 
  while(iStateDoorOpenedSensor == HIGH)
  {
    iStateDoorOpenedSensor = digitalRead(DIN_DOOROPENED);
    g_stepperMotor.step(100);       
  }
  g_stepperMotor.setIdle();
}

void CloseTheDoor()
{
  int iStateDoorClosedSensor;
  iStateDoorClosedSensor = digitalRead(DIN_DOORCLOSED);
 
  while(iStateDoorClosedSensor == HIGH)
  {
    iStateDoorClosedSensor = digitalRead(DIN_DOORCLOSED);
    g_stepperMotor.step(-100);
  }; 
  g_stepperMotor.setIdle();
}

LIGHTLEVEL GetLightLevel()
{
  int iPhotoresistanceValue = analogRead(AIN_PHOTORESISTANCE);
  #ifdef DEBUG_WITH_SERIAL
    Serial.print("Photoresistance: ");
    Serial.print(iPhotoresistanceValue);
    Serial.print("\r\n");
  #endif
  if(iPhotoresistanceValue > DAY_THRESHOLD_VALUE)
  {
    return LIGHTLEVEL_DAY;   
  }
  else if(iPhotoresistanceValue < NIGHT_THRESHOLD_VALUE)
  {
    return LIGHTLEVEL_NIGHT;
  }
  else
  {
    return LIGHTLEVEL_NS;
  }
}

void setup()
{
  SetupInputOutputPin(); 
  SetupMotorSpeed(MOTOR_SPEED);

  #ifndef DEBUG_WITH_SERIAL
    SetupWatchdog(); 
  #else
    SetupSerial();
  #endif
}

void loop()
{
  if (gv_bWdtEvt == true)
  {
    LIGHTLEVEL eLightLevel = GetLightLevel();

    switch(eLightLevel)
    {
      //JOUR
      case LIGHTLEVEL_DAY:
        if(g_ePreviousLightLevelState != LIGHTLEVEL_DAY) //Première détéction du jour
        {                               
          g_ePreviousLightLevelState = LIGHTLEVEL_DAY;
          g_uiSameLightLevelOccurence = 0;
        }
       
        if(g_uiSameLightLevelOccurence >= NB_LIGHT_LEVEL_NEEDS)
        {//Jour détécté plusieurs fois successives
           #ifdef DEBUG_WITH_SERIAL         
            Serial.print("Need to open the door\r\n");     
          #endif
          OpenTheDoor();
          #ifdef DEBUG_WITH_SERIAL
            Serial.print("Door opened\r\n");
          #endif
        }
        else
        {
          g_uiSameLightLevelOccurence++;
        }
        break;

      //NUIT
      case LIGHTLEVEL_NIGHT:   
        if(g_ePreviousLightLevelState != LIGHTLEVEL_NIGHT) //Première détéction de la nuit
        {                               
          g_ePreviousLightLevelState = LIGHTLEVEL_NIGHT;
          g_uiSameLightLevelOccurence = 0;
        }       

        if(g_uiSameLightLevelOccurence >= NB_LIGHT_LEVEL_NEEDS)
        {//Nuit détécté plusieurs fois successives       
           #ifdef DEBUG_WITH_SERIAL
            Serial.print("Need to close the door\r\n");     
          #endif
          CloseTheDoor();
           #ifdef DEBUG_WITH_SERIAL
            Serial.print("Door closed\r\n");
          #endif
        }
        else
        {
          g_uiSameLightLevelOccurence++;
        }
        break;

      //NS (Zone de flottement entre le jour et la nuit servant d'hysteresis)
      default:               
        break;
    }
#ifndef DEBUG_WITH_SERIAL     
    EnterPowerDown(); //Extinction du micro controleur jusqu'a la prochaine interruption (bloquant)
#else
    delay(1000);   
#endif   
  }
  else
  {
    /* Do nothing. */
  } 
}

/*
 * Idle motor consumption.
 */
 void Stepper::setIdle()
{
   if (this->pin_count == 2) {
      digitalWrite(motor_pin_1, LOW);
        digitalWrite(motor_pin_2, LOW);
   }
   if (this->pin_count == 4) {
      digitalWrite(motor_pin_1, LOW);
        digitalWrite(motor_pin_2, LOW);
        digitalWrite(motor_pin_3, LOW);
        digitalWrite(motor_pin_4, LOW);
        digitalWrite(motor_pin_5, LOW);
   }
   if (this->pin_count == 5) {
      digitalWrite(motor_pin_1, LOW);
        digitalWrite(motor_pin_2, LOW);
        digitalWrite(motor_pin_3, LOW);
        digitalWrite(motor_pin_4, LOW);
        digitalWrite(motor_pin_5, LOW);
   }
}

void setIdle();